3.5. Hoeveel uur zijn er verloond?

Concepten

• Arbeidsovereenkomst
• Functie in organisatie-rol
• Onverplaatsbaar artefact
• Verloonde periode
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 3.5 
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
10
11
12SELECT
13  ?Periode
14  (?vestiging AS ?Indeling)
15  (SUM(?verloonde_uren * ?zorg)      AS ?Zorggerelateerd)
16  (SUM(?verloonde_uren * ?niet_zorg) AS ?Niet_Zorggerelateerd)
17  (SUM(?verloonde_uren)              AS ?Totaal)
18WHERE {
19   {
20    #BIND(2024 AS ?jaar)
21    VALUES ?kw { 1 2 3 4 0 }
22
23    BIND(xsd:date(CONCAT(STR(?jaar), "-",
24          IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
25    )) AS ?start_periode)
26
27    BIND(xsd:date(CONCAT(STR(?jaar), "-",
28          IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
29    )) AS ?eind_periode)
30
31    BIND(IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode)
32  }
33
34  # Personeels-overeenkomsten
35  ?overeenkomst
36      a onz-pers:ArbeidsOvereenkomst ;
37      onz-pers:heeftOpdrachtnemer ?persoon ;
38      onz-g:hasPart ?overeenkomst_afspraak .
39
40  ?overeenkomst_afspraak
41      a onz-pers:WerkOvereenkomstAfspraak ;
42      onz-g:startDatum ?start_afspraak ;
43      onz-g:isAbout ?functie ;
44      onz-g:isAbout ?locatie .
45  OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
46  FILTER(?start_afspraak <= ?eind_periode &&
47          ( ?eind_afspraak >= ?start_periode || !BOUND(?eind_afspraak)))
48
49  ?functie a onz-g:OccupationalPositionRole .
50    
51  ?verloonde_periode
52      a onz-fin:VerloondePeriode ;
53      onz-g:definedBy ?overeenkomst ;
54      onz-g:startDatum ?datum_verloonde_periode ;
55      onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?verloonde_uren .
56  FILTER(?datum_verloonde_periode >= ?start_periode &&
57          ?datum_verloonde_periode <= ?eind_periode)
58  FILTER(?datum_verloonde_periode >= ?start_afspraak &&
59          ( ?datum_verloonde_periode <= ?eind_afspraak || !BOUND(?eind_afspraak)))
60
61	?locatie a onz-g:StationaryArtifact ;
62	           onz-g:partOf* ?vestiging_uri .
63    ?vestiging_uri a onz-org:Vestiging .
64    {  
65        	?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
66        	?vest_nr a onz-org:Vestigingsnummer ;
67            onz-g:hasDataValue ?vestiging .
68    } UNION {
69        	# Includeer ook de organisatie als geheel en label deze als vestiging
70        	?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
71        	BIND("Totaal organisatie" AS ?vestiging)
72    }
73
74  # Zorg / niet-zorg indicatoren
75  BIND(IF(EXISTS { ?functie a onz-pers:ZorgverlenerFunctie }, 1, 0) AS ?zorg)
76  BIND(IF(?zorg = 0, 1, 0) AS ?niet_zorg)
77}
78GROUP BY ?Periode ?vestiging
79ORDER BY ?Periode ?vestiging
80